Contract

Contract Source Code (Solidity Standard Json-Input format)

IDE

• Blockscan IDE
• 🤖 Code ReaderBeta

More Options

• Similar
• Submit Audit
• Compare

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.24;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

import "../../Lynx/interfaces/IWrappedNative.sol";
import "../../Lynx/interfaces/ChipEnumsV1.sol";
import "../../Lynx/interfaces/IBurnHandlerV1.sol";
import "../../Lynx/Chips/EngineChip/EngineChip.sol";

/**
 * @title WrappedNativeEngineChipHelper
 * @dev Helper contract for wrapping native tokens and minting engine chips
 */
contract WrappedNativeEngineChipHelper is IBurnHandlerV1 {
    using SafeERC20 for IERC20;

    // ***** Immutable State *****

    IWrappedNative immutable public wrappedNativeToken;
    EngineChip immutable public wrappedNativeEngineChip;

    // ***** Constructor *****

    constructor(address _wrappedNativeEngineChip) {
        wrappedNativeEngineChip = EngineChip(_wrappedNativeEngineChip);

        // sanity
        require(wrappedNativeEngineChip.chipMode() == ChipEnumsV1.ChipMode.LOCAL, "INVALID_CHIP_MODE");

        wrappedNativeToken = IWrappedNative(address(wrappedNativeEngineChip.underlyingToken()));
    }

    // ***** Fallback Functions *****
    receive() external payable {
        // This function is executed when a contract receives plain Native (without data)
    }

    // ***** Wrapped Native Helper Functions *****

    function wrapNativeAndMintEngineChip() external payable {
        // Wrap the native
        uint256 wrappedNativeAmount = wrapNativeInternal(msg.value);

        // Approve usage of wrapped native token
        setAllowanceForChipInternal(wrappedNativeAmount);

        // Mint engine chip
        wrappedNativeEngineChip.mintChip(msg.sender, wrappedNativeAmount);
    }

    function handleBurn(
        address burner,
        uint256, // chipAmount,
        uint256 underlyingAmount,
        bytes calldata // payload
    ) external override payable {
        require(msg.sender == address(wrappedNativeEngineChip), "INVALID_CALLER");

        uint256 unwrappedNativeAmount = unwrapNativeInternal(underlyingAmount);

        payable(burner).transfer(unwrappedNativeAmount);
    }

    // ***** Internal Helper Functions *****

    function wrapNativeInternal(uint256 amount) internal returns (uint256 wrappedNativeAmount) {
        uint256 balanceBefore = IERC20(address(wrappedNativeToken)).balanceOf(address(this));
        wrappedNativeToken.deposit{value: amount}();
        uint256 balanceAfter = IERC20(address(wrappedNativeToken)).balanceOf(address(this));

        wrappedNativeAmount = balanceAfter - balanceBefore;
        require(wrappedNativeAmount == amount, "WRAP_NATIVE_NOT_PRECISE");
    }

    function unwrapNativeInternal(uint256 amount) internal returns (uint256 unwrappedNativeAmount) {
        uint256 balanceBefore = IERC20(address(wrappedNativeToken)).balanceOf(address(this));
        wrappedNativeToken.withdraw(amount);
        uint256 balanceAfter = IERC20(address(wrappedNativeToken)).balanceOf(address(this));

        unwrappedNativeAmount = balanceBefore - balanceAfter;
        require(unwrappedNativeAmount == amount, "UNWRAP_NATIVE_NOT_PRECISE");
    }

    function setAllowanceForChipInternal(uint256 amount) internal {
        IERC20(address(wrappedNativeToken)).approve(address(wrappedNativeEngineChip), 0);
        IERC20(address(wrappedNativeToken)).approve(address(wrappedNativeEngineChip), amount);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in EIP-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     * ```
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.24;

contract ClaimableAdminStorage {
    /**
    * @notice Administrator for this contract
    */
    address public admin;

    /**
    * @notice Pending administrator for this contract
    */
    address public pendingAdmin;

    /*** Modifiers ***/

    modifier onlyAdmin() { require(msg.sender == admin, "ONLY_ADMIN"); _; }

    /*** Constructor ***/

    constructor() {
        // Set admin to caller
        admin = msg.sender;
    }
}



contract AcceptableImplementationClaimableAdminStorage is ClaimableAdminStorage {
    /**
     * @notice Active logic
     */
    address public implementation;

    /**
     * @notice Pending logic
     */
    address public pendingImplementation;
}

contract AcceptableRegistryImplementationClaimableAdminStorage is AcceptableImplementationClaimableAdminStorage {
    /**
     * @notice System Registry
     */
    address public registry;
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.24;

import "./AcceptableImplementationClaimableAdminStorage.sol";

/**
 * @title Claimable Admin
 */
contract ClaimableAdmin is ClaimableAdminStorage {
    /**
      * @notice Emitted when pendingAdmin is changed
      */
    event NewPendingAdmin(address oldPendingAdmin, address newPendingAdmin);

    /**
      * @notice Emitted when pendingAdmin is accepted, which means admin is updated
      */
    event NewAdmin(address oldAdmin, address newAdmin);

    /*** Admin Functions ***/

    /**
      * @notice Begins transfer of admin rights. The newPendingAdmin must call `_acceptAdmin` to finalize the transfer.
      * @dev Admin function to begin change of admin. The newPendingAdmin must call `_acceptAdmin` to finalize the transfer.
      * @param newPendingAdmin New pending admin.
      */
    function _setPendingAdmin(address newPendingAdmin) public {
        // Check caller = admin
        require(msg.sender == admin, "Not Admin");

        // Save current value, if any, for inclusion in log
        address oldPendingAdmin = pendingAdmin;

        // Store pendingAdmin with value newPendingAdmin
        pendingAdmin = newPendingAdmin;

        // Emit NewPendingAdmin(oldPendingAdmin, newPendingAdmin)
        emit NewPendingAdmin(oldPendingAdmin, newPendingAdmin);
    }

    /**
      * @notice Accepts transfer of admin rights. msg.sender must be pendingAdmin
      * @dev Admin function for pending admin to accept role and update admin
      */
    function _acceptAdmin() public {
        // Check caller is pendingAdmin and pendingAdmin ≠ address(0)
        require(msg.sender == pendingAdmin && pendingAdmin != address(0), "Not the EXISTING pending admin");

        // Save current values for inclusion in log
        address oldAdmin = admin;
        address oldPendingAdmin = pendingAdmin;

        // Store admin with value pendingAdmin
        admin = pendingAdmin;

        // Clear the pending value
        pendingAdmin = address(0);

        emit NewAdmin(oldAdmin, admin);
        emit NewPendingAdmin(oldPendingAdmin, pendingAdmin);
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.24;

interface IContractRegistryBase {
    function isImplementationValidForProxy(bytes32 proxyNameHash, address _implementation) external view returns (bool);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.24;

import {ChipEnumsV1} from "../interfaces/ChipEnumsV1.sol";
import "../interfaces/IRegistryV1.sol";

/**
 * @title BaseChip
 * @notice Base for Chip contracts to inherit from, handles the auto approval mechanism.
 */
contract BaseChip is ChipEnumsV1 {

    // ***** Events *****

    event AutoApprovedSpenderSet(string indexed role, address indexed oldSpender, address indexed newSpender);

    // ***** Immutable Storage *****

    IRegistryV1 immutable public registry;
    ChipMode immutable public chipMode;

    // ***** Storage *****

    // address => is auto approved
    mapping(address => bool) public autoApproved;

    // role hash => role address
    mapping(bytes32 => address) public autoApprovedSpendersByRoles;

    // ***** Views *****

    function getAutoApprovedSpenderAddressByRole(string calldata role) public view returns (address) {
        bytes32 roleHash =  keccak256(abi.encodePacked(role));
        return autoApprovedSpendersByRoles[roleHash];
    }

    // ***** Constructor *****

    constructor(IRegistryV1 _registry, ChipMode _chipMode) {
        require(address(_registry) != address(0), "!_registry");

        registry = _registry;
        chipMode = _chipMode;
    }

    // ***** Admin Functions *****

    function setAutoApprovedSpenderForRoleInternal(string calldata role, address spender) internal {
        require(spender == address(0) || registry.getValidSpenderTargetForChipByRole(address(this), role) == spender, "NOT_REGISTRY_APPROVED");

        address oldSpender = getAutoApprovedSpenderAddressByRole(role);

        autoApproved[oldSpender] = false;
        autoApproved[spender] = true;

        bytes32 roleHash =  keccak256(abi.encodePacked(role));
        autoApprovedSpendersByRoles[roleHash] = spender;

        emit AutoApprovedSpenderSet(role, oldSpender, spender);
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.24;

import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";

import "../../interfaces/IPoolMintControllerV1.sol";
import "../../interfaces/IPoolBurnControllerV1.sol";
import "../../interfaces/IBurnHandlerV1.sol";

import "../../../AdministrationContracts/ClaimableAdmin.sol";

import "../BaseChip.sol";

/**
 * @title EngineChip
 * @notice EngineChip is a ERC20 token that functions as a chip for ERC20 tokens that exist in the engin chain
 */
contract EngineChip is ClaimableAdmin, ERC20, ReentrancyGuard, BaseChip {
    using SafeERC20 for IERC20;
    using SafeERC20 for ERC20;

    // ***** Events *****

    event IsMintingPausedSet(bool indexed value);

    event BurnHandlerSet(address indexed previousHandler, address indexed handler);

    event MintControllerSet(address indexed previousController, address indexed newController);
    event BurnControllerSet(address indexed previousController, address indexed newController);

    event TokensSwept(address indexed token, address indexed receiver, uint256 amount);

    event ChipMinted(address indexed minter, address indexed to, uint256 underlyingAmount, uint256 amount);
    event ChipBurned(address indexed burner, address indexed receiver, uint256 underlyingAmount, uint256 amount);

    // ***** Constants *****

    uint public constant SELF_UNIT_SCALE = 1e18;

    // ***** Storage *****

    IERC20 public immutable underlyingToken;

    uint256 public immutable exchangeRate;

    IBurnHandlerV1 public burnHandler;

    bool public isMintingPaused;

    IPoolMintControllerV1 public mintController;
    IPoolBurnControllerV1 public burnController;

    // ***** Constructor *****

    constructor(IRegistryV1 _registry, string memory _name, string memory _symbol, IERC20 _underlyingToken)
    ERC20(_name, _symbol) BaseChip(_registry, ChipMode.LOCAL) {
        require(address(_underlyingToken) != address(0), "!_underlyingToken");
        underlyingToken = _underlyingToken;

        uint underlyingDecimals = ERC20(address(_underlyingToken)).decimals();
        exchangeRate = 10 ** underlyingDecimals;
    }

    // ***** Admin Functions *****

    /**
     * @notice Set the auto approved spender for a role
     * @param role The role to set the spender for
     * @param spender The spender to set
     */
    function setAutoApprovedSpenderForRole(string calldata role, address spender) external onlyAdmin {
        setAutoApprovedSpenderForRoleInternal(role, spender);
    }

    /**
     * @notice Set the burn handler for the pool
     * @param _handler The new burn handler
     */
    function setBurnHandler(IBurnHandlerV1 _handler) external onlyAdmin {
        require(address(_handler) == address(0) || registry.validBurnHandlerForChip(address(this)) == address(_handler), "NOT_REGISTRY_APPROVED");

        address previousHandler = address(burnHandler);

        require(previousHandler != address(_handler), "ALREADY_SET");

        burnHandler = _handler;
        emit BurnHandlerSet(previousHandler, address(_handler));
    }

    /**
     * @notice Set the minting pause state
     * @param _value The new minting pause state
     */
    function setIsMintingPaused(bool _value) external onlyAdmin {
        require(isMintingPaused != _value, "ALREADY_SET");

        isMintingPaused = _value;
        emit IsMintingPausedSet(_value);
    }

    /**
     * @notice Set the mint controller for the pool
     * @param _mintController The new mint controller
     */
    function setMintController(IPoolMintControllerV1 _mintController) external onlyAdmin {
        // Sanity
        require(address(_mintController) == address(0) || _mintController.isPoolMintController(), "NOT_POOL_MINT_CONTROLLER");

        address previousController = address(mintController);

        require(previousController != address(_mintController), "ALREADY_SET");

        mintController = _mintController;

        emit MintControllerSet(previousController, address(_mintController));
    }

    /**
     * @notice Set the burn controller for the pool
     * @param _burnController The new burn controller
     */
    function setBurnController(IPoolBurnControllerV1 _burnController) external onlyAdmin {
        // Sanity
        require(address(_burnController) == address(0) || _burnController.isPoolBurnController(), "NOT_POOL_BURN_CONTROLLER");

        address previousController = address(burnController);

        require(previousController != address(_burnController), "ALREADY_SET");

        burnController = _burnController;

        emit BurnControllerSet(previousController, address(_burnController));
    }

    /**
     * @notice Sweep any non-underlying tokens from the contract
     * @dev Owner can sweep any tokens other than the underlying token
     * @param _token The token to sweep
     * @param _amount The amount to sweep
     */
    function sweepTokens(IERC20 _token, uint256 _amount) external onlyAdmin {
        require(address(_token) != address(underlyingToken), "CANNOT_SWEEP_UNDERLYING_TOKEN");

        _token.safeTransfer(admin, _amount);

        emit TokensSwept(address(_token), admin, _amount);
    }

    /**
     * @notice Sweep native coin from the contract
     * @dev Owner can sweep any native coin accidentally sent to the contract
     * @param _amount The amount to sweep
     */
    function sweepNative(uint256 _amount) external onlyAdmin {
        payable(admin).transfer(_amount);
    }

    // ***** Local Mint/Burn Functions *****

    /**
     * Mint chips to the given address against underlying tokens taken from the caller
     * @param _toAddress The address to mint the chips to
     * @param _amount The amount of underlying tokens to mint against
     */
    function mintChip(address _toAddress, uint256 _amount) external nonReentrant {
        require(!isMintingPaused, "MINT_PAUSED");
        require(_amount != 0, "AMOUNT_ZERO");

        address minter = msg.sender;

        takeUnderlying(minter, _amount);
        uint ownAmountToMint = underlyingAmountToOwnAmountInternal(_amount);

        IPoolMintControllerV1 _mintController = mintController;
        if (address(_mintController) != address(0)) {
            bool isPermitted = _mintController.informMintRequest(minter, _toAddress, _amount, ownAmountToMint);
            require(isPermitted, "MINT_CONTROLLER_REFUSAL");
        }

        _mint(_toAddress, ownAmountToMint);

        emit ChipMinted(minter, _toAddress, _amount, ownAmountToMint);
    }

    /**
     * Burn chips from the caller and transfer the underlying tokens to the 'toAddress'
     * @param _receiver The address to receive the underlying tokens
     * @param _amount The amount of chips to burn
     */
    function burnChip(
        address _receiver,
        uint256 _amount
    ) external nonReentrant {
        address burner = msg.sender;
        safeBurnInternal(burner, _receiver, _amount);
    }

    /**
     * Burn chips from the caller and transfer the underlying tokens to the 'burnHandler' and calls it's 'handleBurn' function
     * @param _amount The amount of chips to burn
     * @param _payload The payload to pass to the burn handler
     */
    function burnChipAndCall(
        uint256 _amount,
        bytes calldata _payload
    ) external payable nonReentrant {
        require(burnHandler != IBurnHandlerV1(address(0)), "NO_BURN_HANDLER");

        // burn the chips
        address burner = msg.sender;
        uint256 underlyingAmount = safeBurnInternal(burner, address(burnHandler), _amount);

        // call the burn handler
        burnHandler.handleBurn{value: msg.value}(burner, _amount, underlyingAmount, _payload);
    }

    // ***** burn internal Functions *****

    /**
     * Safely burns the chips and transfers the underlying tokens to the receiver
     * @param burner The address of the burner
     * @param receiver The address to receive the underlying tokens
     * @param chipAmount The amount of chips to burn
     * @return underlyingAmount The amount of underlying tokens transferred
     */
    function safeBurnInternal(address burner, address receiver, uint256 chipAmount) internal returns (uint256 underlyingAmount) {
        // sanity
        require(chipAmount != 0, "AMOUNT_ZERO");

        // Convert the chip amount to underlying amount
        underlyingAmount = ownAmountToUnderlyingAmountInternal(chipAmount);

        // sanity
        require(underlyingAmount != 0, "UNDERLYING_AMOUNT_ZERO");

        // Inform the burn controller
        IPoolBurnControllerV1 _burnController = burnController;
        if (address(_burnController) != address(0)) {
            bool isPermitted = _burnController.informBurnRequest(burner, receiver, underlyingAmount, chipAmount);
            require(isPermitted, "BURN_CONTROLLER_REFUSAL");
        }

        // Burn the chips
        _burn(burner, chipAmount);

        // Transfer the underlying tokens to the receiver
        underlyingToken.safeTransfer(receiver, underlyingAmount);

        // emit event
        emit ChipBurned(burner, receiver, underlyingAmount, chipAmount);
    }

    // ***** ERC20 internal override Functions *****

    /**
     * @notice Uses the base ERC20 logic unless 'spender' is marked as 'autoApproved'
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        if (autoApproved[spender]) {
            return type(uint).max;
        } else {
            return ERC20.allowance(owner, spender);
        }
    }

    // ***** Underlying utils *****

    /**
     * Utility function to safely take underlying tokens (ERC20) from a pre-approved account
     * @dev Will revert if the contract will not get the exact 'amount' value
     */
    function takeUnderlying(address from, uint amount) internal {
        uint balanceBefore = underlyingToken.balanceOf(address(this));
        underlyingToken.safeTransferFrom(from, address(this), amount);
        uint balanceAfter = underlyingToken.balanceOf(address(this));
        require(
            balanceAfter - balanceBefore == amount,
            "DID_NOT_RECEIVE_EXACT"
        );
    }

    /**
     * Converts the underlying amount to the amount of self tokens by the current exchange rate
     */
    function underlyingAmountToOwnAmountInternal(
        uint256 underlyingAmount
    ) internal view returns (uint256 ownAmount) {
        ownAmount = (underlyingAmount * SELF_UNIT_SCALE) / exchangeRate;
    }

    /**
     * Converts the (self) LP amount to the equal underlying amount by the current exchange rate
     */
    function ownAmountToUnderlyingAmountInternal(
        uint256 ownAmount
    ) internal view returns (uint256 underlyingAmount) {
        underlyingAmount = (ownAmount * exchangeRate) / SELF_UNIT_SCALE;
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.24;

contract ChipEnumsV1 {
    enum ChipMode {
        NONE,
        LOCAL,
        REMOTE,
        HYBRID
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.24;

interface IBurnHandlerV1 {
    function handleBurn(
        address burner,
        uint256 chipAmount,
        uint256 underlyingAmount,
        bytes calldata payload
    ) external payable;
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.24;

interface IGlobalLock {
    function lock() external;
    function freeLock() external;
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.24;

interface IPoolBurnControllerV1 {

    /**
     * @notice Check if the contract is a PoolBurnController
     */
    function isPoolBurnController() external view returns (bool);

    /**
     * @notice Inform the PoolBurnController of a burn request
     * param _burner The address of the account that is burning the tokens
     * param _receiver The address of the account that will receive the underlying tokens
     * param _underlyingAmount The amount of underlying tokens that will be given for burning
     * param _burnAmount The amount of tokens that will be burned
     */
    function informBurnRequest(
        address _burner,
        address _receiver,
        uint256 _underlyingAmount,
        uint256 _burnAmount
    ) external returns (bool isPermitted);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.24;

interface IPoolMintControllerV1 {

    /**
     * @notice Check if the contract is a PoolMintController
     */
    function isPoolMintController() external view returns (bool);

    /**
     * @notice Inform the PoolMintController of a mint request
     * param _minter The address of the account that is minting the tokens
     * param _to The address of the account that is minting the tokens
     * param _underlyingAmount The amount of underlying tokens that were taken for minting
     * param _mintAmount The amount of tokens that will be minted
     */
    function informMintRequest(
        address _minter,
        address _to,
        uint256 _underlyingAmount,
        uint256 _mintAmount
    ) external returns (bool isPermitted);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.24;

import "../../AdministrationContracts/IContractRegistryBase.sol";
import "./IGlobalLock.sol";

interface IRegistryV1Functionality is IContractRegistryBase, IGlobalLock {

    // **** Locking mechanism ****

    function isTradersPortalAndLocker(address _address) external view returns (bool);
    function isTriggersAndLocker(address _address) external view returns (bool);
    function isTradersPortalOrTriggersAndLocker(address _address) external view returns (bool);
}

interface IRegistryV1 is IRegistryV1Functionality {

    // **** Public Storage params ****

    function feesManagers(address asset) external view returns (address);
    function orderBook() external view returns (address);
    function tradersPortal() external view returns (address);
    function triggers() external view returns (address);
    function tradeIntentsVerifier() external view returns (address);
    function liquidityIntentsVerifier() external view returns (address);
    function chipsIntentsVerifier() external view returns (address);


    /**
     * @return The spender role address that is set for this chip
     */
    function getValidSpenderTargetForChipByRole(address chip, string calldata role) external view returns (address);

    /**
     * @return the address of the valid 'burnHandler' for the chip
     */
    function validBurnHandlerForChip(address chip) external view returns (address);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.24;

interface IWrappedNative {
    function deposit() external payable returns (uint256);
    function withdraw(uint256 amount) external returns (uint256);
}

{
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "outputSelection": {
    "*": {
      "*": [
        "evm.bytecode",
        "evm.deployedBytecode",
        "devdoc",
        "userdoc",
        "metadata",
        "abi"
      ]
    }
  },
  "evmVersion": "paris",
  "metadata": {
    "useLiteralContent": true
  },
  "libraries": {}
}

• No Contract Security Audit Submitted- Submit Audit Here

[{"inputs":[{"internalType":"address","name":"_wrappedNativeEngineChip","type":"address"}],"stateMutability":"nonpayable","type":"constructor"},{"inputs":[{"internalType":"address","name":"burner","type":"address"},{"internalType":"uint256","name":"","type":"uint256"},{"internalType":"uint256","name":"underlyingAmount","type":"uint256"},{"internalType":"bytes","name":"","type":"bytes"}],"name":"handleBurn","outputs":[],"stateMutability":"payable","type":"function"},{"inputs":[],"name":"wrapNativeAndMintEngineChip","outputs":[],"stateMutability":"payable","type":"function"},{"inputs":[],"name":"wrappedNativeEngineChip","outputs":[{"internalType":"contract EngineChip","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"wrappedNativeToken","outputs":[{"internalType":"contract IWrappedNative","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"stateMutability":"payable","type":"receive"}]

60c060405234801561001057600080fd5b50604051610b50380380610b5083398101604081905261002f91610186565b6001600160a01b03811660a052600160a0516001600160a01b0316635b0cc8c46040518163ffffffff1660e01b8152600401602060405180830381865afa15801561007e573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906100a291906101c0565b60038111156100b3576100b36101aa565b146100f85760405162461bcd60e51b8152602060048201526011602482015270494e56414c49445f434849505f4d4f444560781b604482015260640160405180910390fd5b60a0516001600160a01b0316632495a5996040518163ffffffff1660e01b8152600401602060405180830381865afa158015610138573d6000803e3d6000fd5b505050506040513d601f19601f8201168201806040525081019061015c9190610186565b6001600160a01b0316608052506101e1565b6001600160a01b038116811461018357600080fd5b50565b60006020828403121561019857600080fd5b81516101a38161016e565b9392505050565b634e487b7160e01b600052602160045260246000fd5b6000602082840312156101d257600080fd5b8151600481106101a357600080fd5b60805160a0516108f86102586000396000818160ce01528181610122015281816101940152818161045f0152610513015260008181606101528181610266015281816102d5015281816103710152818161048e01528181610542015281816105d50152818161065901526106e701526108f86000f3fe6080604052600436106100435760003560e01c806317fcb39b1461004f57806321a02efe1461009f57806343aa8ca1146100a9578063b61c41ee146100bc57600080fd5b3661004a57005b600080fd5b34801561005b57600080fd5b506100837f000000000000000000000000000000000000000000000000000000000000000081565b6040516001600160a01b03909116815260200160405180910390f35b6100a76100f0565b005b6100a76100b73660046107b7565b610189565b3480156100c857600080fd5b506100837f000000000000000000000000000000000000000000000000000000000000000081565b60006100fb34610244565b905061010681610448565b60405163ec1a5abb60e01b8152336004820152602481018290527f00000000000000000000000000000000000000000000000000000000000000006001600160a01b03169063ec1a5abb90604401600060405180830381600087803b15801561016e57600080fd5b505af1158015610182573d6000803e3d6000fd5b5050505050565b336001600160a01b037f000000000000000000000000000000000000000000000000000000000000000016146101f75760405162461bcd60e51b815260206004820152600e60248201526d24a72b20a624a22fa1a0a62622a960911b60448201526064015b60405180910390fd5b6000610202846105b3565b6040519091506001600160a01b0387169082156108fc029083906000818181858888f1935050505015801561023b573d6000803e3d6000fd5b50505050505050565b6040516370a0823160e01b815230600482015260009081906001600160a01b037f000000000000000000000000000000000000000000000000000000000000000016906370a0823190602401602060405180830381865afa1580156102ad573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906102d19190610859565b90507f00000000000000000000000000000000000000000000000000000000000000006001600160a01b031663d0e30db0846040518263ffffffff1660e01b815260040160206040518083038185885af1158015610333573d6000803e3d6000fd5b50505050506040513d601f19601f820116820180604052508101906103589190610859565b506040516370a0823160e01b81523060048201526000907f00000000000000000000000000000000000000000000000000000000000000006001600160a01b0316906370a0823190602401602060405180830381865afa1580156103c0573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906103e49190610859565b90506103f08282610872565b92508383146104415760405162461bcd60e51b815260206004820152601760248201527f575241505f4e41544956455f4e4f545f5052454349534500000000000000000060448201526064016101ee565b5050919050565b60405163095ea7b360e01b81526001600160a01b037f000000000000000000000000000000000000000000000000000000000000000081166004830152600060248301527f0000000000000000000000000000000000000000000000000000000000000000169063095ea7b3906044016020604051808303816000875af11580156104d7573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906104fb9190610899565b5060405163095ea7b360e01b81526001600160a01b037f000000000000000000000000000000000000000000000000000000000000000081166004830152602482018390527f0000000000000000000000000000000000000000000000000000000000000000169063095ea7b3906044016020604051808303816000875af115801561058b573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906105af9190610899565b5050565b6040516370a0823160e01b815230600482015260009081906001600160a01b037f000000000000000000000000000000000000000000000000000000000000000016906370a0823190602401602060405180830381865afa15801561061c573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906106409190610859565b604051632e1a7d4d60e01b8152600481018590529091507f00000000000000000000000000000000000000000000000000000000000000006001600160a01b031690632e1a7d4d906024016020604051808303816000875af11580156106aa573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906106ce9190610859565b506040516370a0823160e01b81523060048201526000907f00000000000000000000000000000000000000000000000000000000000000006001600160a01b0316906370a0823190602401602060405180830381865afa158015610736573d6000803e3d6000fd5b505050506040513d601f19601f8201168201806040525081019061075a9190610859565b90506107668183610872565b92508383146104415760405162461bcd60e51b815260206004820152601960248201527f554e575241505f4e41544956455f4e4f545f505245434953450000000000000060448201526064016101ee565b6000806000806000608086880312156107cf57600080fd5b85356001600160a01b03811681146107e657600080fd5b94506020860135935060408601359250606086013567ffffffffffffffff8082111561081157600080fd5b818801915088601f83011261082557600080fd5b81358181111561083457600080fd5b89602082850101111561084657600080fd5b9699959850939650602001949392505050565b60006020828403121561086b57600080fd5b5051919050565b8181038181111561089357634e487b7160e01b600052601160045260246000fd5b92915050565b6000602082840312156108ab57600080fd5b815180151581146108bb57600080fd5b939250505056fea26469706673582212202c058a1cdd496dfe257b5096bdfe3567b7d5851ab08fe39b90b8287cff5ace9f64736f6c63430008180033000000000000000000000000614aa983f54409d475aec5d18120fecfd6320ef4

0x6080604052600436106100435760003560e01c806317fcb39b1461004f57806321a02efe1461009f57806343aa8ca1146100a9578063b61c41ee146100bc57600080fd5b3661004a57005b600080fd5b34801561005b57600080fd5b506100837f00000000000000000000000021be370d5312f44cb42ce377bc9b8a0cef1a4c8381565b6040516001600160a01b03909116815260200160405180910390f35b6100a76100f0565b005b6100a76100b73660046107b7565b610189565b3480156100c857600080fd5b506100837f000000000000000000000000614aa983f54409d475aec5d18120fecfd6320ef481565b60006100fb34610244565b905061010681610448565b60405163ec1a5abb60e01b8152336004820152602481018290527f000000000000000000000000614aa983f54409d475aec5d18120fecfd6320ef46001600160a01b03169063ec1a5abb90604401600060405180830381600087803b15801561016e57600080fd5b505af1158015610182573d6000803e3d6000fd5b5050505050565b336001600160a01b037f000000000000000000000000614aa983f54409d475aec5d18120fecfd6320ef416146101f75760405162461bcd60e51b815260206004820152600e60248201526d24a72b20a624a22fa1a0a62622a960911b60448201526064015b60405180910390fd5b6000610202846105b3565b6040519091506001600160a01b0387169082156108fc029083906000818181858888f1935050505015801561023b573d6000803e3d6000fd5b50505050505050565b6040516370a0823160e01b815230600482015260009081906001600160a01b037f00000000000000000000000021be370d5312f44cb42ce377bc9b8a0cef1a4c8316906370a0823190602401602060405180830381865afa1580156102ad573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906102d19190610859565b90507f00000000000000000000000021be370d5312f44cb42ce377bc9b8a0cef1a4c836001600160a01b031663d0e30db0846040518263ffffffff1660e01b815260040160206040518083038185885af1158015610333573d6000803e3d6000fd5b50505050506040513d601f19601f820116820180604052508101906103589190610859565b506040516370a0823160e01b81523060048201526000907f00000000000000000000000021be370d5312f44cb42ce377bc9b8a0cef1a4c836001600160a01b0316906370a0823190602401602060405180830381865afa1580156103c0573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906103e49190610859565b90506103f08282610872565b92508383146104415760405162461bcd60e51b815260206004820152601760248201527f575241505f4e41544956455f4e4f545f5052454349534500000000000000000060448201526064016101ee565b5050919050565b60405163095ea7b360e01b81526001600160a01b037f000000000000000000000000614aa983f54409d475aec5d18120fecfd6320ef481166004830152600060248301527f00000000000000000000000021be370d5312f44cb42ce377bc9b8a0cef1a4c83169063095ea7b3906044016020604051808303816000875af11580156104d7573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906104fb9190610899565b5060405163095ea7b360e01b81526001600160a01b037f000000000000000000000000614aa983f54409d475aec5d18120fecfd6320ef481166004830152602482018390527f00000000000000000000000021be370d5312f44cb42ce377bc9b8a0cef1a4c83169063095ea7b3906044016020604051808303816000875af115801561058b573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906105af9190610899565b5050565b6040516370a0823160e01b815230600482015260009081906001600160a01b037f00000000000000000000000021be370d5312f44cb42ce377bc9b8a0cef1a4c8316906370a0823190602401602060405180830381865afa15801561061c573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906106409190610859565b604051632e1a7d4d60e01b8152600481018590529091507f00000000000000000000000021be370d5312f44cb42ce377bc9b8a0cef1a4c836001600160a01b031690632e1a7d4d906024016020604051808303816000875af11580156106aa573d6000803e3d6000fd5b505050506040513d601f19601f820116820180604052508101906106ce9190610859565b506040516370a0823160e01b81523060048201526000907f00000000000000000000000021be370d5312f44cb42ce377bc9b8a0cef1a4c836001600160a01b0316906370a0823190602401602060405180830381865afa158015610736573d6000803e3d6000fd5b505050506040513d601f19601f8201168201806040525081019061075a9190610859565b90506107668183610872565b92508383146104415760405162461bcd60e51b815260206004820152601960248201527f554e575241505f4e41544956455f4e4f545f505245434953450000000000000060448201526064016101ee565b6000806000806000608086880312156107cf57600080fd5b85356001600160a01b03811681146107e657600080fd5b94506020860135935060408601359250606086013567ffffffffffffffff8082111561081157600080fd5b818801915088601f83011261082557600080fd5b81358181111561083457600080fd5b89602082850101111561084657600080fd5b9699959850939650602001949392505050565b60006020828403121561086b57600080fd5b5051919050565b8181038181111561089357634e487b7160e01b600052601160045260246000fd5b92915050565b6000602082840312156108ab57600080fd5b815180151581146108bb57600080fd5b939250505056fea26469706673582212202c058a1cdd496dfe257b5096bdfe3567b7d5851ab08fe39b90b8287cff5ace9f64736f6c63430008180033

000000000000000000000000614aa983f54409d475aec5d18120fecfd6320ef4

-----Decoded View---------------
Arg [0] : _wrappedNativeEngineChip (address): 0x614aA983f54409D475aeC5D18120FECFD6320eF4

-----Encoded View---------------
1 Constructor Arguments found :
Arg [0] : 000000000000000000000000614aa983f54409d475aec5d18120fecfd6320ef4